NanoC (二) ADC数模转换器 | 电位器 | 蜂鸣器

Philsjy

模拟信号与数字信号转换 - ADC实验

一、模拟信号与数字信号

在学习 ADC 之前，我们要首先学习什么是模拟信号，什么是数字信号。

特性	模拟信号	数字信号
时间	连续	离散
幅值	连续	离散
示例	温度变化、天体运动等	网络传输数据、电子钟表

模拟信号与数字信号

我们举个简单的例子：

指针时钟显示的就是时间的模拟信号，他表示时间是连续变化的；
数字时钟显示的就是时间的数字信号，时间的显示是按照固定增量变化的，他可以显示 1、2、3，但是无法显示 1.1、2.1、等，所以在数字电路中使用的数字信号一般只能取 0 或 1，把 0 对应为低电平，把 1 对应为高电平，所以有或者没有数字信号是在模拟信号的基础上依次经过 采样、量化、编码而形成的；

ADC 工作原理

采样 就是把输入的模拟信号按适当的时间间隔得到各个时刻的样本值；
量化 是把经采样测得的各个时刻的值用二进制码来表示；
编码则是把量化生成的二进制数排列在一起形成顺序脉冲序列。

二、模数转换器 (ADC)

（一）ADC 的功能

定义：ADC（Analog to Digital Converter）将模拟信号转换为数字信号。
应用：将变化的电压转成数字信号供单片机处理。

（二）输入电压范围

默认配置下，ADC 引脚输入电压必须在 0 和 5V 之间。
超过 5.0V 的值将读为 1023。
可通过配置衰减器增加测量范围。
Arduino Uno模拟输入功能有10位精度，即可以将0～5V的电压信号转换为0～1023的整数形式表示。

三、元器件介绍

（一）电位器

电位器相当于一个滑动变阻器，两端引脚阻值是固定的，中间引脚对任何一端的引脚阻值是可变的，他等效于从中间把电位器分成两个串联的电阻，串联总阻值是确定的，一端接输入电源，一端接地。

电位器样式有很多种，下图是常见的立式长柄电位器。

我们开发板上的是阻值为203(20K)的卧式电位器，封装体积很小，适合板载。

（二）蜂鸣器

蜂鸣器是一种将电信号转换为声音信号的器件，常用来产生设备的按键音、报警音等提示信号。

蜂鸣器按驱动方式可分为有源蜂鸣器和无源蜂鸣器:

有源蜂鸣器：内部自带振荡源，将正负极接上直流电压即可持续发声，频率固定；

无源蜂鸣器：内部不带振荡源，需要控制器提供振荡脉冲才可发声，调整提供振荡脉冲的频率，可发出不同频率的声音；

注意：

开发板上采用的是有源蜂鸣器；
有的无源蜂鸣器顶部会标有正负极，印有+号的为正极，或者若蜂鸣器引脚没剪，则长的为正极；
面包板上外接的无源蜂鸣器不用区分正负极。

四、程序设计

（一）利用`analogRead`读取电位器模拟值输入

首先我们打开Arduino IDE，可以点击左上角文件 -> 新建项目；
当然你也可以打开一个例程文件，通过修改或重写文件里的代码实现功能，示例文件打开路径参见下图。

接下来编写程序，以下是参考代码：

#define POT A3  // 定义电位器输入引脚  

int pot_value;  // 用于存储电位器的值  

void setup() {  
 
  Serial.begin(115200);  // 初始化串口通信，波特率115200  
  pinMode(POT, INPUT);   // 设置引脚为输入模式  
   
}  

void loop() {  
  // 主循环，重复运行的代码  
  pot_value = analogRead(POT);  // 从引脚读取电位器的模拟值  
    
  Serial.println(pot_value);  // 打印读取的电位器值
  delay(50);  // 延迟50毫秒，以稳定读取  
}

编译运行；
在运行代码之前，先确认开发板已连接上位机（电脑）并在Arduino IDE中选择NanoE的开发板；
详情请参考上篇教程NanoC (一) 环境安装

然后点击左上角的→，就可以编译运行啦~
代码编译成功并上传后，在工具中查找，或直接点击页面右上方小图标，打开内置的串口监视器；
设置底部串口监视器波特率为115200，旋转开发板上的卧式电位器，观察底部串口监视器输出变化；

可以看到输入的模拟值变化范围在0-1023。

（二）利用`analogRead()`和`map()`映射函数驱动有源蜂鸣器

接下来新建项目，以下是示例代码：

#define POT A3  // 定义A3为电位器输入引脚  
#define BUZZER 4  // 定义数字4引脚为蜂鸣器输出引脚  

int pot_value;  // 用于存储电位器的模拟值  
int buzzer_freq;  // 存储映射后的蜂鸣器频率  

void setup() {  
  Serial.begin(115200);  // 初始化串口通信，设置波特率为115200  
  pinMode(POT, INPUT);   // 设置引脚A3为输入模式  
  pinMode(BUZZER, OUTPUT);  // 设置引脚4为输出模式  
}  

void loop() {  
  // 读取电位器的模拟值 (范围 0-1023)  
  pot_value = analogRead(POT);  

  // 将电位器的值映射到蜂鸣器支持的频率范围，比如500Hz到2000Hz(可调)
  buzzer_freq = map(pot_value, 0, 1023, 500, 2000);   

  // 使用 tone() 函数控制蜂鸣器发出对应频率的声音  
  tone(BUZZER, buzzer_freq);  
  
  // 在串口端打印电位器的模拟值  
  Serial.print("Potentiometer Value: ");  
  Serial.println(pot_value);  

  delay(50);  // 延迟50毫秒以稳定读取  
}

代码编译成功并上传后，旋转开发板上的卧式电位器，左下角的蜂鸣器发出会发出不同频率的声音。至此，我们实现了数模转换器（ADC）的功能，将电位器的模拟信号转换为数字信号，以便后续处理和控制蜂鸣器的发声频率。

（三）无源蜂鸣器的使用

我们编写一个 Arduino 程序，简单展示下无源蜂鸣器的使用，通过无源蜂鸣器自动播放《小星星》。
下面是示例代码：

#define BUZZER 4  // 定义无源蜂鸣器的引脚为数字 4  

// 小星星的音符频率（单位：Hz）  
int melody[] = {  
  262, 262, 392, 392, 440, 440, 392, // 一闪一闪亮晶晶  
  349, 349, 330, 330, 294, 294, 262, // 满天都是小星星  
  392, 392, 349, 349, 330, 330, 294, // 挂在天上放光明  
  392, 392, 349, 349, 330, 330, 294, // 好像许多小眼睛  
  262, 262, 392, 392, 440, 440, 392, // 一闪一闪亮晶晶  
  349, 349, 330, 330, 294, 294, 262  // 满天都是小星星  
};  

// 每个音符的时长（单位：毫秒）  
int noteDurations[] = {  
  400, 400, 400, 400, 400, 400, 800,  
  400, 400, 400, 400, 400, 400, 800,  
  400, 400, 400, 400, 400, 400, 800,  
  400, 400, 400, 400, 400, 400, 800,  
  400, 400, 400, 400, 400, 400, 800,  
  400, 400, 400, 400, 400, 400, 800  
};  

void setup() {  
  pinMode(BUZZER, OUTPUT);  // 设置无源蜂鸣器为输出模式  
}  

void loop() {  
  // 遍历每个音符  
  for (int i = 0; i < sizeof(melody) / sizeof(melody[0]); i++) {  
    int noteDuration = noteDurations[i];  // 获取当前音符的时长  
    
    tone(BUZZER, melody[i], noteDuration);  // 播放音符  
    
    delay(noteDuration * 1.3);  // 增加音符之间的间隔，让音乐更自然  
  }  
  
  delay(2000);  // 播放完成后暂停2秒，循环播放  
}

电路连接图
我们将NanoC单片机从开发板上取下，在面包板上搭建电路，接线方式如下图：
完成程序编译上传后，无源蜂鸣器就开始“歌唱”《小星星》了。